一. Fortran 字符串与 C 字符串的区别
Fortran的字符串处理能力其实很弱，关于字符串的语法还很落后。它与 C 字符串最大的区别就是：Fortran字符串是固定长度的，没有 \0 结束符。另外，Fortran 也不区分字符和字符串。即 'abc' 与 "abc" 是没有差别的。
二. Fortran 字符串的定义。
Fortran字符串是固定长度的。因此，在声明时，就必须指定长度。（如不指定，大多数编译器认为是长度为 1 的字符串）
声明时，可以按照这些格式进行：
integer , parameter :: L = 20 character :: s1*20 = "fcode.cn" character*20 :: s2 = "fcode.cn" character(20) :: s3 = "fcode.cn" character( len = 20 ) :: s4 = "fcode.cn" character( len = L ) :: s5 = "fcode.cn"
目前，笔者不建议使用第2行和第3行的方式。第4行的方式还算凑合。建议最好是使用第5行的方式，第6行演示了长度可以使用 parameter 常数，这样适合于需要大量定义相同长度的字符串。
三. Fortran字符串的长度问题
需要注意的是，字符串的长度一旦确定了，就无法改变。这一点笔者也感到语法应该改进，很不方便。
例如上例。character( Len = 20 ) :: s4 = "fcode.cn" 尽管后面的值 "fcode.cn" 只有 8 个字符，但是定义了变量是 20 长度，所以，实际 s4 的内容为 "fcode.cn "（后面有12个空格）
如果我们要输出或使用字符串，往往需要去掉后面的空格，此时可使用 trim 函数。
write(*,*) trim(s4)
这样，就只会输出有内容的 8 个字符，后面的 12 个空格就不会输出。
特别需要注意的是，s4 = trim(s4) 这样的句子是没有任何意义的。因为虽然这个式子的右侧，trim(s4) 的结果是 8 个字符，但赋值给式子左侧的字符串，它依然是 20 长度。它等效于 s4 = "fcode.cn"，所以 s4 的内容依然是 “fcode.cn ”（读者可回去看上面的绿色文字）
这让我们很犯难。因此，trim 语句必须出现在每一次使用这个字符串的时候。
四. Fortran 字符串的连接（append）
我们经常会挂靠字符串，比如 "fcode.cn" 在后面挂靠一个 "/bbs"，很多初学者就会使用这样的代码：
character( Len = 20 ) :: s4 = "fcode.cn"
s4 = s4 // "/bbs"
输出以后，发现 s4 的内容依然没有改变。并没有变成期望中的 "fcode.cn/bbs"。究其原因，其实就是第三个问题导致的。我们来观察上面的等式：s4 = s4 // "/bbs"，等号左边 s4 有 20 长度，等号右边 s4 的 20 长度加上 "/bbs" 的 4 长度，一共 24 个长度。左边20个长度根本容纳不下右边的24个长度，于是，s4 依然是 s4，后面挂靠的 "/bbs" 由于存储不下而被丢弃。
正确的挂靠方式是： s4 = trim(s4) // "/bbs"
而反之，s4 = "http://" // s4 就不需要写 trim，请读者朋友自己思考为什么？
五. 字符串的左右对齐（AdjustL，AdjustR）
我们经常会遇到这样的问题，除了后面的空格外，有时候字符串前面也有空格。例如 s4 = " FortranCoder "，单一的 trim 结果会是 " FortranCoder"。
此时我们就需要 AdjustL 函数，我们可以这样写： trim(AdjustL(s4)) , 或者 AdjustL(trim(s4)) 这两者的顺序无所谓，结果都是一样的。
AdjustR 函数使用的情况非常少，通常不用。它可以把 " abc " 变为 " abc"
六. 字符串与整型，实型的相互转换
Fortran 的字符串与整型实现转换，是个很有意思的事情。它不像其他语言那样，提供一个函数来进行。而使用 read 和 write 读写来实现。
看下面的例子：
Program www_fcode_cn Implicit None Real :: r Integer :: i Character( Len = 20 ) :: c c = "3.1415926" read( c , * ) r !// 将 字符串c 转换为实数 r write( * , * ) r + 1.0 i = int( r - 2.0 ) !// 给 i 一个值 write( c , '(i0)' ) i !// 把整型i 转换为字符串 c c = AdjustL(trim(c)) // "st" write( * , * ) Trim( c ) End Program www_fcode_cn
这里的第 7 行，看起来是一个 read 语句，它其实是转换。意思是：从字符串 c 中读取 r 的值。读者可以把此时的字符串 c 想成是一个虚拟的文件。
这里的第 10 行，看起来是一个 write 语句，其实它还是转换。意思是：把 i 的值，写入字符串 c 中，读者依然可以想象成 c 是一个虚拟的文件。
简单的说，就是 read 和 write 语句，可以直接对字符串进行操作。字符串可以被认为是虚拟的文件，从字符串中获得数值，就是read；把值写入到字符串中，就是write。
七. 一个实例
这里，我们列举一个实际字符串使用的例子。
假设现在有一个文件，其内容如下：
// This is a sample file
// There may be some comment text
Time:13:23:42 RecordID:18 Weather:Sunny
Fcode.cn Date:2014-02-38
前两行是注释，而且有可能不是两行，不确定有多少行。
然后是一些数据组合在一起。我们需要找到 RecordID: 后面的数字，即，18。我们事先不能确定 RecordID 在第几行的什么位置里。
找到之后，我们需要给它加上 2014，即，2014+18=2032。
最后我们打开 File2031.dat 文件，开始读取其中的数据。
上面的一系列操作，如果不使用字符串，恐怕会很难。下面我们来看看如何书写代码来完成。利用本文所提到的各种内容。
代码中有一部分注释，相信读者朋友能够理解
Program www_fcode_cn
Implicit None
Integer , parameter :: MAX_PATH = 512
Character( Len = MAX_PATH ) :: c
Character( Len = * ) , parameter :: STR_FIND = "RecordID:"
integer :: ID , i , iErr
Open( 12 , File = "fcode.txt" )
Do
Read( 12 , '(a512)' , ioStat = iErr ) c !必须a512格式,否则遇到空格会终止
if ( iErr /= 0 ) Exit !// 如果读错了，比如遇到文件结束，则退出循环
if ( c(1:2) == "//" ) cycle !// 如果读取的是注释行，则直接读下一行
i = index( c , STR_FIND ) !// 在 c 中搜索 RecordID: 的位置
if ( i > 0 ) then !// 如果找到
i = i + Len(STR_FIND) !// 将位置移到RecordID:后面
c = c(i:) !// 使得 c 的内容为 i 位置之后的内容，即放弃i位置之前的内容
read( c , * ) ID !// 读取 ID 编号
write( c , * ) ID + 2014 !// ID 编号加上2014，再写回c中
c = "File" // Trim(AdjustL(c)) // ".dat" !组合成File2032.dat,注意trim
write( * , * ) Trim( c ) !// 输出看看对不对
!// Open( 13 , File = Trim( c ) )
Exit
end if
End Do
Close( 12 )
End Program www_fcode_cn
